YouTube Script v3.5

; YouTube Script v3.5 - by entropy 2019
; Syntax: !yt <search> or  paste a youtube link in any channel.
 
#youtube on
on *:text:*:#:{ doyoutube $1- }
on *:input:#:{ if ($server && /* !iswm $1) { doyoutube $1- } }
 
alias -l doyoutube {
  if ($wildtok($1-,*https://www.youtube.com/watch?v=*,1,32)) { var %a = $v1 | youtube # %a }
  elseif ($wildtok($1-,*https://youtu.be/*,1,32)) { var %a = $v1 | youtube # %a }
  elseif (?yt iswm $1 && $left($1,1) isin @!.) { youtubesearch # $2- }
}
alias -l youtube {
  sockclose youtube
  sockopen -e youtube youtube.com 443
  %youtubechannel = $1
  %site = $2
  unset %duration
}
 
on *:sockopen:youtube:{
  if ($sockerr) { return }
  sockwrite -nt $sockname GET %site HTTP/1.1
  sockwrite -nt $sockname Host: www.youtube.com
  sockwrite -nt $sockname Connection: Close
  sockwrite -nt $sockname Accept-Language: en-us  
  sockwrite -nt $sockname Content-Type: text/html
  sockwrite -nt $sockname $str($crlf,2)  
}
 
on *:sockread:youtube:{
  if ($sockerr) { return }
  var %a
  sockread -f %a
  tokenize 32 %a
  ;echo -s > $1-
 
  if (Location: == $1) { sockclose $sockname | youtube %youtubechannel $2- | return }
 
  if (* aria-label="dislike this video along with * iswm $1- && $remove($nohtml($1-),$chr(44)) isnum) {
    %down = $nohtml($1-)
    sockclose $sockname
    endyoutube
  }
  if (* aria-label="like this video along with * iswm $1- && $remove($nohtml($1-),$chr(44)) isnum) { 
    %up = $nohtml($1-)
  }
  if (*</ul></div></div></div><div id="watch8-sentiment-actions"><div id="watch7-views-info"><div class="watch-view-count">* views</div>* iswm $1-) {
    %views = $remove($nohtml($1-),views)
  } 
 
  if (<title> isin $1- && <title>YouTube</title> !isin $1) {
    var %p = $replace($1-,>,$+(>,$chr(32)),<,$+($chr(32),<))
    var %end = $findtok(%p,</title>,1,32)
    dec %end 3
    var %z = $gettok(%p,$+(2-,%end),32)
    var %z = $remove(%z,<title>,</title>,- YouTube)
    %line = %z
  }
}
on *:sockclose:youtube:{ endyoutube }
 
alias -l endyoutube {
  if (%line) {
    if ($len(%line) >= 50) { %line = $+($gettok(%line,1-50,32),...) }
    msg %youtubechannel [YouTube] $chr(9679) $replace($html(%line),",",&,&) $chr(9679) Views: $iif(%views,$v1,NA) $chr(9679) Up: $iif(%up,$v1,0) $chr(9679) Down: $iif(%down,$v1,0)
  }
  else { msg %youtubechannel [YouTube] $chr(9679) No such video! }
  unset %line %views %up %down %youtubechannel %site %duration
}
 
alias -l nohtml {
  return $regsubex($1, /<[^>]+(?:>|$)|^[^<>]+>/g,)
}
alias -l html {
  var %a = 1, %b, %n, %c, %total = $1-
  while ($gettok(%total,%a,59)) {
    %b = $v1
    %n = $+(&,$gettok(%b,-1,38))
    if (&#* iswm %n) {
      %c = $remove(%n,$chr(59),$chr(38),$chr(35))
      %total = $replace(%total,%n,$chr(%c))
    }
    inc %a
  }
  return $remove(%total,;)
}
 
 
; YouTube Search
alias -l youtubesearch {
  sockclose youtubesearch
  sockopen -e youtubesearch youtube.com 443
  %youtubechannel = $1
  %search = $replace($2-,$chr(35),$+($chr(37),23))
}
on *:sockopen:youtubesearch:{
  if ($sockerr) { msg %youtubechannel [YouTube] $chr(9679) Open ERROR! | unset %youtubechannel %search | return }
  sockwrite -nt $sockname GET $+(/results?search_query=,$replace(%search,$chr(32),+)) HTTP/1.1
  sockwrite -nt $sockname Host: www.youtube.com
  sockwrite -nt $sockname Connection: Close
  sockwrite -nt $sockname Content-Type: text/html
  sockwrite -nt $sockname Accept-Language: en-us  
  sockwrite -nt $sockname $crlf  
}
on *:sockread:youtubesearch:{
  if ($sockerr) { msg %youtubechannel [YouTube] $chr(9679) Read ERROR! | unset %youtubechannel %search | return }
  var %a
  sockread -f %a
  tokenize 32 %a
  ;tokenize 32 $replace($mid(%a,1,4000),$chr(62),$+($chr(62),$chr(32)),$chr(60),$+($chr(32),$chr(60)))
 
  if ($1) {
    if (*:* iswm $nohtml($1-)) {
      var %a = $wildtok($nohtml($1-),*:*,1,32), %b = $wildtok($nohtml($1-),*:*,2,32)
      %duration = $remove($gettok($iif(%a == Duration:,%b,%a),1,46),a,b,c,d,e,f,g,h,i,j,k,l,m,n,o,p,q,r,s,t,u,v,w,x,y,z)
      ;echo 09 -a > %duration
    }
    if (*<h3 class="yt-lockup-title "><a href="/watch?v=*" * iswm $1-) {
      %video = $nohtml($gettok($+(https://www.youtube.com,$remove($5,href=,")),1,$asc(&)))
 
      %line = $replace($gettok($nohtml($6-),1-,46),- Duration:,$chr(32))
 
      %line = $replace(%line,ft.,ft,feat.,feat)
 
      %line = $gettok(%line,1,46)
      if ($gettok(%line,-1,32) isnum) { %line = $gettok(%line,1--2,32) }
 
      ;echo 07 -s > %line
      if (*:* iswm $gettok(%line,-1,32)) {  
        %duration = $v2
        %line = $remove(%line,$v2)
      }
      else { %duration = NA }
 
      if (* PlaylistYouTube* iswm %line) { %line = $replace(%line,playlistyoutube,$+(playlistyoutube,$chr(32))) }
      if (* Playlist* iswm %line) { %line = $replace(%line,playlist,$+(playlist,$chr(32))) }
 
      %line = $gettok(%line,1- $+ $calc( $findtok(%line,playlistyoutube,1,32) - 1),32)
      %line = $gettok(%line,1- $+ $calc( $findtok(%line,playlist,1,32) - 1),32)
 
      if ($gettok(%line,-1,32) == -) { %line = $gettok(%line,1--2,32) }
 
      %line = $remove(%line,class="yt-uix-tile-link,yt-ui-ellipsis yt-ui-ellipsis-2 yt-uix-sessionlink,title="," rel="spf-prefetch" aria-describedb,")
 
      if ($gettok(%line,1,32) == spf-link) { %line = $gettok(%line,3--1,32) }
      if (y=description- isin $1-) { %line = $remove(%line,y=description-) }
 
      if ($len(%line) >= 50) { %line = $+($gettok(%line,1-50,32),...) }
 
      %line = $gettok(%line,1,124)
 
      msg %youtubechannel [YouTube Search] $chr(9679) $replace($html($nohtml(%line)),",",&,&,",",&,&) $chr(9679) Duration: %duration $chr(9679) URL: $replace(%video,&,&)
      set -u5 %finished yes
      sockclose $sockname
      endyoutubesearch
    }
    if (</html> isin $1-) { endyoutubesearch }
  }
}
 
alias -l endyoutubesearch {
  if (!%finished) { msg %youtubechannel [YouTube Search] $chr(9679) No such video! }
  unset %youtubechannel %video %line %search %finished %duration
}
#youtube end